1.繪制彎矩圖
建立彎矩單元表。例如梁單元
i節(jié)點單元表名稱為imom，j節(jié)點單元表名稱為jmom，
ETABLE,NI,SMISC,1     !單元I點軸力
ETABLE,NJ,SMISC,7     !單元J點軸力
ETABLE,QI,SMISC,2     !單元I點剪力
ETABLE,QJ,SMISC,8     !單元J點剪力
ETABLE,MI,SMISC,6     !單元I點彎矩
ETABLE,MJ,SMISC,12 !單元J點彎矩
plls,imom,jmom
2.標(biāo)注彎矩圖
PLOTCTRLS>>NUMBERING>>SVAL ON即可在畫出彎矩圖的同時在圖上標(biāo)出彎矩值的大小
3.調(diào)整彎矩圖
如果彎矩圖方向錯誤，則繪制彎矩圖命令為
plls,imom,jmom，-1
同一個節(jié)點處兩邊的單元內(nèi)力有細(xì)微差別，
導(dǎo)致內(nèi)力數(shù)字標(biāo)注出現(xiàn)重影。觀察上面整體軸力圖也可以發(fā)現(xiàn)，
一段一段的，好像馬賽克，其實上面整體彎矩圖也是，不過不是
很明顯罷了。這是EULER-BEONOULI梁理論以及ANSYS輸出定義造成
的（詳細(xì)原因就不展開了，看看梁理論的書和ANSYS的說明吧）。
為了修正重影和節(jié)點兩邊內(nèi)力值不一樣的問題，遍制了宏文件ITFAVG.MAC
命令文件內(nèi)容如下：
!---------------------------------------------------------------------
!宏：ITFAVG.MAC（INTERNAL FORCE AVERAGE MACRO）
!獲取線性單元內(nèi)力，并對單元邊界處的內(nèi)力進(jìn)行平衡
!輸入信息
!內(nèi)力類型：MFORX,MFORY,MFORZ,MMOMX,MMOMY,MMOMZ
*ASK,ITFTYPE,'PLEASE INPUT THE TYPE OF INTERNAL FORCE','MMOMY'
!需處理的單元包
*ASK,EASSEMBLY,'PLEASE INPUT THE COMPONENT NAME OF ELEMENTS TO BE PROCESSED!',
'EOUTER'
!需處理的節(jié)點包
*ASK,NASSEMBLY,'PLEASE INPUT THE COMPONENT NAME OF NODE TO BE PROCESSED!','NOU
TER'
!無需處理的節(jié)點包
*ASK,UNASSEMBLY,'PLEASE INPUT THE COMPONENT NAME OF THE UNCHANGED NODE!(NONE I
F THERE'S NO SUCH COMPONENT)','NONE'
/POST1
!輸入信息：內(nèi)力類型，欲處理單元的集合，欲處理節(jié)點的集合
!ITFTYPE='MMOMY'
!EASSEMBLY='EOUTER'
!NASSEMBLY='NOUTER'
!按內(nèi)力類型確定ANSYS輸出信息SMISC的編號
*IF,ITFTYPE,EQ,'MFORX',THEN
ITFINUM=1
ITFJNUM=7
*ELSEIF,ITFTYPE,EQ,'MFORY',THEN
ITFINUM=2
ITFJNUM=8
*ELSEIF,ITFTYPE,EQ,'MFORZ',THEN
ITFINUM=3
ITFJNUM=9
*ELSEIF,ITFTYPE,EQ,'MMOMX',THEN
ITFINUM=4
ITFJNUM=10
*ELSEIF,ITFTYPE,EQ,'MMOMY',THEN
ITFINUM=5
ITFJNUM=11
*ELSEIF,ITFTYPE,EQ,'MMOMZ',THEN
ITFINUM=6
ITFJNUM=12
*ELSE
*ENDIF
!對不需平均的節(jié)點進(jìn)行處理
*IF,UNASSEMBLY,NE,'NONE',THEN
!選出不進(jìn)行處理的節(jié)點包并獲取不進(jìn)行處理節(jié)點的數(shù)目
CMSEL,S,UNASSEMBLY
*GET,UNNODNUM,NODE,0,COUNT
!定義長度為UNNODNUM的數(shù)組（UNNOD），以存放選中單元的單元編號
*DIM,UNNOD,ARRAY,UNNODNUM
!將選中單元的編號按順序存入數(shù)組UNNOD
*DO,I,0,UNNODNUM-1,1
UNNOD(I+1)=NDNEXT(I)
*ENDDO
*ELSE
UNNODNUM=0
*ENDIF
!選出所需的單元和節(jié)點包
CMSEL,S,EASSEMBLY
CMSEL,S,NASSEMBLY
!獲得當(dāng)前選中單元總數(shù)（存入變量SELELENUM）
*GET,SELELENUM,ELEM,0,COUNT
!定義長度為SELELENUM的數(shù)組（ELENUM），以存放選中單元的單元編號
*DIM,ELENUM,ARRAY,SELELENUM
!將選中單元的編號按順序存入數(shù)組ELENUM
*DO,I,0,SELELENUM-1,1
ELENUM(I+1)=ELNEXT(I)
*ENDDO
!獲得當(dāng)前選中節(jié)點總數(shù)（存入變量SELNODNUM）
*GET,SELNODNUM,NODE,0,COUNT
!定義長度為SELNODNUM的數(shù)組（NODNUM），以存放選中單元的單元編號
*DIM,NODNUM,ARRAY,SELNODNUM
!將選中單元的編號按順序存入數(shù)組NODNUM
*DO,I,0,SELNODNUM-1,1
NODNUM(I+1)=NDNEXT(I)
*ENDDO
!定義所需的線性單元內(nèi)力ETABLE，節(jié)點I的內(nèi)力存入數(shù)組ITNFI,
!節(jié)點J的內(nèi)力存入數(shù)組ITNFJ
ETABLE,ITNFI,SMISC,ITFINUM
ETABLE,ITNFJ,SMISC,ITFJNUM
!定義所需的結(jié)果數(shù)組，并將其置零
ETABLE,ITNFINEO,SMISC,5
SADD,ITNFINEO,ITNFI,,1
ETABLE,ITNFJNEO,SMISC,11
SADD,ITNFJNEO,ITNFJ,,1
*DO,K,1,SELNODNUM,1
!處理不需平均的節(jié)點
INDEX=0
*IF,UNNODNUM,GE,1,THEN
*DO,J,1,UNNODNUM
*IF,NODNUM(K),EQ,UNNOD(J),THEN
INDEX=1
*ELSE
*ENDIF
*ENDDO
*ELSE
*ENDIF
*DO,J,1,SELELENUM,1
!選出和節(jié)點K相連的線性單元中，I節(jié)點（對線性單元而言）為節(jié)點K的單元編號
*IF,NELEM(ELENUM(J),1),EQ,NODNUM(K),THEN
ELEI=ELENUM(J)
*EXIT
*ELSE
*ENDIF
*ENDDO
*DO,J,1,SELELENUM,1
!選出和節(jié)點K相連的線性單元中，J節(jié)點（對線性單元而言）為節(jié)點K的單元編號
*IF,NELEM(ELENUM(J),2),EQ,NODNUM(K),THEN
ELEJ=ELENUM(J)
*EXIT
*ELSE
*ENDIF
*ENDDO
*IF,INDEX,EQ,0,THEN
*IF,ELEJ,NE,0,THEN !有可能出現(xiàn)ELEJ為0的情況
!取出I節(jié)點為節(jié)點K的單元的I節(jié)點端的內(nèi)力放入?yún)?shù)ETELEI
*GET,ETELEI,ELEM,ELEI,ETAB,ITNFI
!取出J節(jié)點為節(jié)點K的單元的J節(jié)點端的內(nèi)力放入?yún)?shù)ETELEJ
*GET,ETELEJ,ELEM,ELEJ,ETAB,ITNFJ
!平均節(jié)點K的單元的I節(jié)點端的內(nèi)力和節(jié)點K的單元的J節(jié)點端的內(nèi)力
ETAVE=(ETELEI+ETELEJ)/2
!將平均后的內(nèi)力存入結(jié)果數(shù)組中
DETAB,ELEI,ITNFINEO,ETAVE
DETAB,ELEJ,ITNFJNEO,ETAVE
*ELSE
*ENDIF
*ELSE
*ENDIF
*ENDDO
/UDOC,1,LOGO,OFF
PLLS,ITNFINEO,ITNFJNEO
!END OF ITFAVG.MAC
（2）
對體和面來說，ANSYS默認(rèn)的結(jié)果輸出格式是云圖格式，而這種彩色云圖打印為黑白圖像時對比很不明顯，無法表達(dá)清楚，對于發(fā)表文章非常不便。發(fā)文章所用的結(jié)果圖最好是等值線圖，并且最好是黑白的等值線圖。一般借用photoshop等第三方軟件，很麻煩，效果也不好。ansys本身也能實現(xiàn)這項功能。
1.將要輸出的結(jié)果調(diào)出，這時為彩色云圖；
2.將云圖轉(zhuǎn)換為等值線圖的形式
GUI：plotCtrls—>Device Options—>[/DEVI]中的vector mode 選為on
命令：/DEVICE,VECTOR,1
這時結(jié)果為彩色等值線，若直接輸出，打印為黑白圖像時仍然不清晰，為此需進(jìn)行以下幾步將圖像轉(zhuǎn)換為黑白形式；
3. 將背景變?yōu)榘咨?
命令：jpgprf,500,100,1
/rep
4.對等值線中的等值線符號（圖中為A,B,C等）的疏密進(jìn)行調(diào)整
GUI：plotCtrls—>Style—>Contours—> Contours Labeling 在Key Vector mode contour label 中選中on every Nth elem，然后在N= 輸入框中輸入合適的數(shù)值，例如5，多試幾次，直到疏密合適
命令：/clabel,1,5
5.將彩色等值線變?yōu)楹谏?
GUI：plotCtrls—>Style—>Colors—>Contours Colors 將Items Numbered 1，Items Numbered 2等復(fù)選框中的顏色均選為黑色，圖像即可變?yōu)楹诎椎戎稻€圖像
命令：/color,cntr,whit,1 等等
6.修改
在顯示等值線時，圖形中太多的標(biāo)識字母（A、B等）使得等值線圖完全看不清楚。請問有沒有什么方法可以去掉圖形的這些標(biāo)識字母呢
在plotCtrls下面的style下面的contours下面的contour Labeling，在彈出的contour labeling options里面的vector mode contour labels選off
后處理中畫出了結(jié)構(gòu)的等值線圖，可否將等值線邊的字母改為相應(yīng)的數(shù)值標(biāo)注
/PNUM,SVAL,1
/replot
如果還想將等值線的字母去掉
/PNUM,SVAL,1
/CLABEL,1,-1
/replot
7.出圖
GUI：plotCtrls—>Capture Image