一般，在我們的印象里，電場要么為“靜電場”，要么為“恒定電場”。這兩類在ANSYS中一般分別可以采用Plane121和Plane68單元來解決(僅以2D為例)。

實際上，上述求解相當于“電路”中純“電容”或“電阻”電路，但有時如果“電容”和“電阻”效應相當時，如何解決呢？如一塊受潮的絕緣介質，在交流條件下其中電場如何分布呢？

這就是——時諧電場(Harmonic Electric Field)。

經過本人試驗，得到如下結論：

1 時諧電場版本：

時諧電場為ANSYS10.0推出的新功能，ANSYS8.0之前不具備。

2 時諧電場單元：

Plane121, Plane230。本人僅試驗2D條件下這兩個單元，也許其它單元也有此功能，但未驗證，主要需要查看單元所要求的“材料屬性”。

3 特點：

   體現了“靜電場”的電容特性，“恒定電流”場的電流特性。所以最后可以求電容、損耗、導納這一類問題。

4 算例程序：

    一個平行版電容導納的求解問題。

! Part 1: Initializing data about the system;

  a=9.e-2                        ! radius, m

  d=0.1e-2                       ! thickness, m

  epsr=1143                      ! relative permittivity

  tand=0.0105                    ! loss tangent

  Vo=50                         ! voltage amplitude, V

  f1=0                           ! begin frequency, Hz

  f2=1E6                        ! end frequency, Hz

  eps0=8.854e-12                 ! free space permittivity, F/m

  Pi=acos(-1)

  C=epsr*eps0*Pi*a**2/d          ! capacitance, F

  P2d=Pi*f2*Vo**2*C*tand         ! power dissipation at freq. f2, Watt

! Part 2: Creating and meshing model;

  /PREP7

  et,1,PLANE230,,,1              ! axisymmetric electric element

  !emunit,epzro,eps0              ! specify free-space permittivity

  mp,perx,1,epsr                 ! electric material properties

  mp,lsst,1,tand

  rect,,a,,d                     ! model and mesh

  esize,d/2

  Amesh,1

! Part 3: Boundary conditions and loads

  nsel,s,loc,y,0

  cp,1,volt,all                  ! define bottom electrode

  *get,n_grd,node,0,num,min      ! get master node on bottom electrode

  nsel,s,loc,y,d

  cp,2,volt,all                  ! top electrode

  *get,n_load,node,0,num,min     ! get master node on top electrode

  nsel,all

  d,n_grd,volt,0                 ! ground bottom electrode

  d,n_load,volt,Vo               ! apply voltage load to top electrode

  Finish

! Part 4: Solving the harmonic electric field;

  /solu

  antype,harm                    ! harmonic analysis

  harfrq,f1,f2                   ! frequency range

  nsubs,10                       ! number of substeps

  outres,all,all                 ! write all solution items to the result file

  kbc,1                          ! stepped load

  solve

  Finish

! Part 5；Postprocedures;

  /post1                        

  /com,Calculate power dissipation at frequency = %f2%, Hz

  set,last                     ! read last data set

  Etab,jh,jheat                ! fill etable with Joule heat rates per unit volume

  Etab,vol,volu                ! fill etable with element volumes

  Smult,dpower,jh,vol          ! fill etable with element Joule heat rates

  Ssum                           ! sum element Joule heat rates

  /com,Expected power dissipation = %P2d%, Watt

  Finish

! Part 6: TimeHist___postprocedure

  /post26

  RForce,2,n_load,amps         ! reaction current I

  Prod,3,2,,,Y_ANSYS,,,1/Vo    ! Y_ansys = I/V

  Prod,4,1,,,,,,2*Pi*C           ! 2*Pi*f*C

  cfact,tand,,,1

  add,5,4,4,,Y_TARGET            ! Y_target = 2*Pi*f*C*(tand+j)

  prcplx,1

  prvar,Y_ANSYS,Y_TARGET

  Finish